#SingleInstance ignore

TitleClock = Plasma's Clock

Menu, Tray, Tip, %TitleClock%
Menu, Tray, NoStandard
Menu, Tray, Add, 顯示時鐘, ShowGui
Menu, Tray, Add
Menu, Tray, Add, 保持在最上層, AlwaysOnTop
Menu, Tray, Add, 不要關閉 (縮至系統列), CloseToTray
Menu, Tray, Add, 顯示月曆, UseCalerdar
Menu, Tray, Add
Menu, Tray, Add, 結束, CloseClock
Menu, Tray, Default, 顯示時鐘
Menu, Tray, Click, 1
OnTop = -1
; 如果要預設「保持在最上層」，就改成 OnTop = 1
; 並且加入這一列：
; Menu, Tray, Check, 保持在最上層
MinOnly = -1
; 如果要預設「縮至系統列」，就改成 MinOnly = 1
; 並且加入這一列：
; Menu, Tray, Check, 不要關閉 (縮至系統列)
Calendar = 1
Menu, Tray, Check, 顯示月曆

Goto, InitGui

UseCalerdar:
Menu, Tray, ToggleCheck, 顯示月曆
Calendar := Calendar * -1

ShowGui:
IfWinExist, %TitleClock%
{
  WinGetPos, X, Y, , , %TitleClock%
  Gui, Destroy
}
InitGui:
if (X = "") {
X = Center
}
if (Y = "") {
Y = Center
}
Menu, Tray, Enable, 不要關閉 (縮至系統列)
Gui, Add, GroupBox, w300 h35, Time
Gui, Font, S12, Verdana
Gui, Add, Text, vMyClock xp+2 y18 wp-4 h20 center, %A_YYYY%/%A_MM%/%A_DD% %A_DDDD% %A_Hour%:%A_Min%
Gui, Font, S8, Verdana
if (Calendar > 0) {
  Gui, Add, MonthCal, R2 x25 y50 vMyCalendar
}
Gui, Show, x%X% y%Y%, %TitleClock%
save_wday := A_WDay
if (OnTop > 0) {
  WinSet, AlwaysOnTop, On, %TitleClock%
}
Loop {
  Sleep, 60000 - ( A_Sec * 1000 + A_MSec )
  GuiControl, , MyClock, %A_YYYY%/%A_MM%/%A_DD% %A_DDDD% %A_Hour%:%A_Min%
  if save_wday <> A_WDay 
  { 
    GuiControl, , MyCalendar, %A_Now% 
    save_wday := A_WDay 
  }
}

CloseClock:
ExitApp

AlwaysOnTop:
Menu, Tray, ToggleCheck, 保持在最上層
WinSet, AlwaysOnTop, Toggle, %TitleClock%
OnTop := OnTop * -1
return

CloseToTray:
Menu, Tray, ToggleCheck, 不要關閉 (縮至系統列)
MinOnly := MinOnly * -1
return

GuiClose:
if (MinOnly > 0) {
  Menu, Tray, Disable, 不要關閉 (縮至系統列)
  WinGetPos, X, Y, , , %TitleClock%
  Gui, Destroy
}
if (MinOnly < 0) {
  ExitApp
}